1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

[Setup]
AppName=Bingo Card Creator
AppVerName=Bingo Card Creator 2.51
AppPublisher=Bingo Card Creator
AppPublisherURL=http://www.bingocardcreator.com/
AppSupportURL=http://www.bingocardcreator.com/
AppUpdatesURL=http://www.bingocardcreator.com/
;Installs into Program Files by default.
DefaultDirName={pf}\Bingo Card Creator
DisableDirPage=yes
DisableReadyPage=yes
DefaultGroupName=Bingo Card Creator
DisableProgramGroupPage=yes
LicenseFile=license.txt
;Call this one BBCINative.exe for internal reference.  Web server will rename to BCCI.exe
OutputBaseFilename=BingoCardCreatorInstallerNative
OutputDir = .
Compression=lzma
SolidCompression=yes

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Files]
Source: "BingoCardCreator.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "readme.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "license.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "SampleLists\*"; DestDir: "{app}\SampleLists"; Excludes: "svn"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "rt\*"; DestDir: "{app}\rt"; Excludes: "svn"; Flags: ignoreversion recursesubdirs createallsubdirs
; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Icons]
Name: "{group}\Bingo Card Creator"; Filename: "{app}\BingoCardCreator.exe"; WorkingDir: "{app}"
Name: "{group}\{cm:UninstallProgram,Bingo Card Creator}"; Filename: "{uninstallexe}"
Name: "{commondesktop}\Bingo Card Creator"; Filename: "{app}\BingoCardCreator.exe"; WorkingDir: "{app}"

[Run]
;Unpacks rt-0.jar.pack into rt-0.jar right before install completes.
Filename: "{app}\rt\bin\unpack200"; WorkingDir: "{app}\rt\lib"; Parameters: "-r rt-0.jar.pack rt-0.jar"; Flags: runhidden
Filename: "{app}\BingoCardCreator.exe"; Description: "{cm:LaunchProgram,Bingo Card Creator}"; WorkingDir: "{app}"; Flags: nowait postinstall skipifsilent

[UninstallDelete]
Type: files; Name: "{app}\license.ini";
Type: files; Name: "{app}\update*.ini";
Type: filesandordirs; Name: "{app}\My Lists";
Type: filesandordirs; Name: "{app}\SampleLists";
Type: filesandordirs; Name: "{app}\rt";
Type: dirifempty; Name: "{app}";


[Registry]
;These four keys associate BCC with .bcf files
Root: HKCR; Subkey: ".bcf"; ValueType: string; ValueName: ""; ValueData: "BingoCardCreatorFile"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "BingoCardCreatorFile"; ValueType: string; ValueName: ""; ValueData: "Bingo Card File"; Flags: uninsdeletekey
Root: HKCR; Subkey: "BingoCardCreatorFile\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\BingoCardCreator.exe,0"; Flags: uninsdeletekey
; I am a lazy bugger -- finding your installed directory in Java is needlessly hard, so to circumvent that problem I just have Windows tell me where it is, either via the working directory (for launching from shortcuts) or via a command line parameter (for shell integration).
Root: HKCR; Subkey: "BingoCardCreatorFile\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\BingoCardCreator.exe"" ""{app}"" ""%1"""; Flags: uninsdeletekey