1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: dryes <joswiseman@gmail>
# Contributor: Dan Serban
# Contributor: Vishnevsky Roman <aka dot x0x01 at gmail dot com>
# Contributor: Massimiliano Torromeo <[email protected]>

pkgname=sphinx
pkgver=2.0.3
pkgrel=1
pkgdesc="Free open-source SQL full-text search engine"
arch=(i686 x86_64)
url=http://www.sphinxsearch.com/
license=(GPL)
depends=(unixodbc expat libmysqlclient)
optdepends=(postgresql)
backup=(etc/conf.d/sphinx)
source=("http://sphinxsearch.com/files/$pkgname-$pkgver-release.tar.gz"
	sphinx.conf.d
	sphinx.rc.d)

build() {
	cd "$srcdir/$pkgname-$pkgver-release"
	./configure --prefix=/usr --exec-prefix=/usr \
		--program-prefix="sphinx-" --localstatedir=/var/lib/sphinx --sysconfdir=/etc/sphinx \
		--enable-id64
	make
}

package() {
	cd "$srcdir/$pkgname-$pkgver-release"
	make DESTDIR="$pkgdir" install
	install -Dm755 "$srcdir"/sphinx.rc.d "$pkgdir"/etc/rc.d/sphinx
	install -Dm644 "$srcdir"/sphinx.conf.d "$pkgdir"/etc/conf.d/sphinx
}

md5sums=('a1293aecd5034aa797811610beb7ba89'
         '48e3e1857919d26d5104a48caffb531b'
         'd886222593c6bba891fd3ce982c90c00')